@Echo off
cls
SETLOCAL ENABLEEXTENSIONS
SETLOCAL ENABLEDELAYEDEXPANSION
if "%*"=="" Goto :ShowUsage
if "%~2"=="" Goto :ShowUsage
 
SET RootKey="HKLM\software\Microsoft\Windows NT\CurrentVersion\ProfileList"
Set Val=ProfileImagePath
 
Call SET CurProf=%%USERPROFILE%%
SET CurSID=""
 
Echo Determining Current User's SID ...
Call :GETSID %RootKey%
Echo The current users SID is %CurSID%
Call Set RegTmp=%Temp%\%CurSID%_SearchScopes.reg
 
IF "%1"=="export" Call :ExportScopes "%~2"
IF "%1"=="import" Call :ImportScopes "%~2"
 
Echo.
echo Done Processing
echo.
pause
echo.
Goto :EOF
 
 
:GETSID
FOR /F "tokens=7* delims=\" %%i IN ('REG QUERY "%~1"') DO (
  FOR /F "tokens=2*" %%a in ('REG QUERY "%~1\%%~i" /v %Val% ^|FINDSTR %Val%') DO (
     CALL SET ldclientdir=%%b
     if "%CurProf%"=="!ldclientdir!" (
       Set CurSID=%%~i
     )
  )
)
GOTO :EOF
 
:ExportScopes
echo Exporting Search Scope Settings ...
REG Export "HKU\%CurSID%\Software\Microsoft\Internet Explorer\SearchScopes" %RegTmp%>Nul 2>&1
Echo Replacing SID with place-holder CURRENTUSERSID ...
Call :SandR %RegTmp% "%~1" %%CurSID%% CURRENTUSERSID
goto :eof
 
:SandR
::1 = input file
::2 = output file
::3 = search string
::4 = replacement value
if EXIST "%~2" DEL /Q "%~2"
for /f "tokens=1,* delims=]" %%a in ('"type "%~1"|find /n /v """') do (
   CALL SET _result=%%b
   if NOT "%%b"=="" (
     CALL SET _fchar=%%_result:~0,1%%
     if "!_fchar!"=="[" (
       set "line=%%b"
       if defined line (
          call set "line=echo.%%line:%3=%4%%"
          for /f "delims=" %%X in ('"echo."%%line%%""') do %%~X>>"%~2"
       )   ELSE echo.>>"%~2"
     ) else (
         echo %%b>>"%~2"
     )
   ) else (
       echo.>>"%~2"
   )
)
goto :eof
 
:ImportScopes
if NOT EXIST "%~1" GOTO :ShowUsage
echo Preparing Registry Data for Import ...
echo Replacing place-holder CURRENTUSERSID with SID ...
if EXIST %RegTmp% Del %RegTmp%
Call :SandR "%~1" %RegTmp% CURRENTUSERSID %%CurSID%%
Echo Importing Search Scopes ...
if EXIST %RegTmp% REG Import %RegTmp%>NUL 2>&1
goto :eof
 
 
:ShowUsage
cls
echo.
echo USAGE
echo   Script.bat import^|export IMPORTFILE.REG^|OUTPUTFILE.REG
echo.
echo Example Export of current Search Scopes to a file 
echo with the name MySearchScopes to the local directory C:\Data
echo.
echo   Script.bat export c:\Data\MySearchScopes.reg
echo.
Echo Example Import of Search Scopes from file generated via this script
Echo.
Echo  script.bat import c:\import\MySearchScopes.reg
echo.
pause
echo.